[agog]

şöyle bir şey'i nasıl yapabilirim, fikri olan varsa sevinirim;

http://www.sitem.com/sayfam.ASP?gelen=şıkıdım
şeklinde bir sorgudan gelen değişkeninin değerini çekip sorunsuz şekilde yazdırabiliyorum, fakat ben şöyle birşey olsun istiyorum;

http://www.sitem.com/şıkıdım
yani sayfam.ASP?gelen= kısmını atıp, sadece şıkıdım değerini çekerek ekrana yazdırmak istiyorum.

istediğim şeyi 404 hata iletisinde yönlendirilen sayfa yardımıyla yaptım sayılır ama, birinci haliyle ekrana doğru yazılan şıkıdım değeri, yapmak istediğim ikinci haliyle "%C5%9F%C4%B1k%C4%B1d%C4%B1m" olarak yazılıyor, kodlarım karaktersizlik ediyor yani. bu durumda ne yapabilirim? önerilerinizi bekliyorum.

[stalker]

urldecode etmen gerekiyor,

[agog]

urldecode derken, replace ile gelen karakterleri düzeltmem gerektiğini mi söylüyorsunuz? şayet böyle ise " ı " için ie "%C4%B1" gibi bir çıktı verirken Firefox "%FD" çıktısı veriyor, türkçe karakterlerin her biri için Firefox ve ie 'ye göre replace fonksiyonunu mu kullanmalıyım?

teşekkür ederim ayrıca ilgilendiğin için.

[stalker]

Function URLDecode(ByVal What)
'URL decode Function
'2001 Antonin Foller, PSTRUH software, http://www.motobit.com
  Dim Pos, pPos

  'replace + To Space
  What = Replace(What, "+", " ")

  on error resume Next
  Dim Stream: Set Stream = CreateObject("ADODB.Stream")
  If err = 0 Then 'URLDecode using ADODB.Stream, If possible
    on error goto 0
    Stream.Type = 2 'String
    Stream.Open

    'replace all %XX To character
    Pos = InStr(1, What, "%")
    pPos = 1
    Do While Pos > 0
      Stream.WriteText Mid(What, pPos, Pos - pPos) + _
        Chr(CLng("&H" & Mid(What, Pos + 1, 2)))
      pPos = Pos + 3
      Pos = InStr(pPos, What, "%")
    Loop
    Stream.WriteText Mid(What, pPos)

    'Read the text stream
    Stream.Position = 0
    URLDecode = Stream.ReadText

    'Free resources
    Stream.Close
  Else 'URL decode using string concentation
    on error goto 0
    'UfUf, this is a little slow method. 
    'Do Not use it For data length over 100k
    Pos = InStr(1, What, "%")
    Do While Pos>0 
      What = Left(What, Pos-1) + _
        Chr(Clng("&H" & Mid(What, Pos+1, 2))) + _
        Mid(What, Pos+3)
      Pos = InStr(Pos+1, What, "%")
    Loop
    URLDecode = What
  End If
End Function

response.write urldecode(request("gelen"))

[agog]

teşekkürler tekrardan.

[PsyChaos]

Daha kısa hali ile;

<%
Private Function UrlDecode(byVal Text)
Text = Replace(Replace(Text,"%","")," ","")
For x = 1 To 255 : Application(Hex(x)) = chr(x) : Next
For i = 1 To Len(Text) Step 2
tText = tText & Application(Mid(Text,i,2))
Next
UrlDecode = tText
End Function
%>

[Dd_LynCh]

Sayfanın ismini değişken olarak alıp kullanabilir miyiz??

Şöyle ki...

../iletisim.ASP?sayfa=iletisim

şeklinde yazdığım adresin sonundaki ?sayfa=iletisim'den kurtulmak istiyorum. Bana sadece iletisim.ASP gerek. Mümkün müdür??

[absconder]

şu şekilde mümkün:

iis içerisinde web site properties ten custom errors tan message type url verip mesela root taki /default.ASP ye yönlendirirsiniz,

Request.QueryString size "404;http://arwen:80/ddfgdfg " değeri döndürür, bol olan değeri kolayca split edip kullababilirsiniz.

yalnız, .net için bu çözüm VIEWSTATE leri bozduğu için çok da geçerli bir yol değildir. (ki bunun anlamı, formlar post edilememek demektir), ASP için rahatça kullanabilirsiniz...

bide şu var mesela link şu şekilde <a href="?iletisim">İLETİŞİM</a>, sonrası ise şöyle;
<%
dim strContent
strContent = request.querystring

select case strContent
case "iletisim"
%><!-- #include file="iletisim.inc.ASP" --><%
case "haberler"
%><!-- #include file="haberler.inc.ASP" --><%
case "anasayfa"
%><!-- #include file="default.inc.ASP" --><%
case else
%><!-- #include file="default.inc.ASP" --><%
end select
%>
diye bi kodla bunu yapabilirsin. tabi tek fazlası ? oluyor bu durumda...