[erdalmemisch]

Örneğin;
querystring 'i 1 den 99 'a kadar olan bir sayfam var ve bu sayfadan ASPTear veya XMLHTTP ile verileri almak istiyorum. Fakat 1 den 99 'a kadar say diye kurduğum döngü ne ASPTear da ne de XMLHTTP'de çalışıyor. Sorunu anlayamadım, çünkü dögüyü yazdırdığımda çalışıyor bir sorun yok ama ASPTear veya XMLHTTP de çalışmıyor.

<%
abc = "http://localhost/sayfa.ASP?id="
for i = 1 to 99
url = abc & i
next

Public Function alsana(al_gali)
Set objalsana = server.CreateObject("Microsoft.XMLHTTP" )
objalsana.Open "GET",al_gali,FALSE
objalsana.sEnd
alsana = objalsana.Responsetext
SET objalsana = Nothing
End Function

strURL = url
strVeri = alsana(strURL)
sonuc = Mid(strVeri,1,999999999)

'Kodun sağlaması ve çalıştığının delili burada.
for m = 1 to 99
response.write abc & m & "<br>"
next

Set baglanti = server.CreateObject("ADODB.Connection")
baglanti.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & server.MapPath("db.mdb")
SQL = "Select * from tablo where hucre ='" & url & "'"
set rs = server.CreateObject("ADODB.RecordSet")
rs.open SQL,baglanti,1,3

if rs.recordcount = 0 then
rs.addnew
rs("url") = url
rs("sonuc") = sonuc
rs.update
end if

rs.movenext
'next
rs.Close
Set rs=Nothing
Baglanti.Close
Set Baglanti=Nothing
%>

[absconder]

rs.movenext ten dolayı hata veriyor olabilir. kodunuzda

rs.movenext
'next
rs.Close

kısmını silerseniz ve veritabanına yazma izni verirseniz hatasız çalışıyor olacaktır.

belki algoritmanız yanlıştır,. yapmak istediğiniz sayfa.ASP nin id si 1 den 99 a kadar olan HTML çıktılarını almak ise algoritmanın kesinlikle yanlış olduğunu söyleyebilirim. çünkü strURL değeri nihai olarak sayfa.ASP?id=99 oluyor ve sadece bu değer için içerik almaya çalışıyor.

yapmak istediğinizi ve hata kodunu yazarsanız daha iyi sonuçlar elde edebilirsiniz.

[erdalmemisch]

@absconder ilgin için teşekkür ederim.
Söylediğiniz kısmı kaldırıpta denedim ama yine sadece idsi 99 olan sayfası kaydediyor.

Benim istediğim 1'den 99 kadar tüm sayfaları kaydetmek.
Evet, sayfa.ASP nin id si 1 den 99 a kadar olan HTML 'nin tüm çıktılarını almak istiyorum.

[absconder]

dediğim gibi, algoritma yanlış. aşağıdaki kod işinizi görür sanırım.

<%
abc = "http://localhost/sayfa.ASP?id="

Public Function alsana(al_gali)
	Set objalsana = server.CreateObject("Microsoft.XMLHTTP" )
	objalsana.Open "GET",al_gali,FALSE
	objalsana.sEnd
	alsana = objalsana.Responsetext
	SET objalsana = Nothing
End Function

Set baglanti = server.CreateObject("ADODB.Connection")
baglanti.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & server.MapPath("db.mdb")

for i = 1 to 99
	url = abc & i
	strURL = url
	strVeri = alsana(strURL)
	sonuc = Mid(strVeri, 1, 999999999)

	SQL = "Select * from tablo where hucre ='" & url & "'"
	set rs = server.CreateObject("ADODB.RecordSet")
	rs.open SQL,baglanti,1,3

	if rs.recordcount = 0 then rs.addnew
	rs("url") = url
	rs("sonuc") = sonuc
	rs.update
	Set rs=Nothing
next

Baglanti.Close
Set Baglanti=Nothing
%>