[CreaNext]

XML'i ASP ile okumayı bir çok örneklerle inceledim ama olayı anlayamadım.

<basla>
<kayit_id>15</kayit_id>
<kayit_ad>kalem</kayit_ad>
<not>kırmızı</not>
</basla>

şu tarz bir XML'i ASP ile nasıl okuyabilirim açıklamalı olarak anlatabilirmisiniz.
Ayrıca bu "selectNodes" , "GetAttribute" gibi kelimlerin işlevleri nelerdir.?
Şimdiden Teşekkürler.

[absconder]

en basit hali ile aşağıdaki gibi okuyabilirsiniz;

<%
XMLStr = "<?XML version='1.0' encoding='windows-1254' ?>" &_
	" <root>" &_
	"	<basla kayit_id='15' att='15-1'>" &_
	"		<kayit_ad>kalem</kayit_ad>" &_
	"		<not>kırmızı</not>" &_
	"	</basla>" &_
	"	<basla kayit_id='16' att='16'>" &_
	"		<kayit_ad>kağıt</kayit_ad>" &_
	"		<not>beyaz</not>" &_
	"	</basla>" &_
	"	<basla kayit_id='15' att='15-2'>" &_
	"		<kayit_ad>silgi</kayit_ad>" &_
	"		<not>siyah</not>" &_
	"	</basla>" &_
	" </root>"

set objXML = server.CreateObject("Microsoft.XMLDOM")

'eğer dosayadan okuyacaksanız
'success = XML.load("file.XML")

'eğer text olarak elde etmişseniz
success = objXML.loadXml(XMLStr)

If CBool(success) then 
	For i = 0 To objXML.DocumentElement.childNodes.length - 1
		Response.Write "kayıt id : " & objXML.DocumentElement.childNodes(i).getAttribute("kayit_id")& "<br>"
		Response.Write "kayıt adı : " & objXML.DocumentElement.childNodes(i).childNodes(0).text & "<br>"
		Response.Write "not : " & objXML.DocumentElement.childNodes(i).childNodes(1).text & "<br><br>"
	Next
End If

Response.Write "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~<br><br>"

' kayit_id'si 15 olan basla node'larını seçmek için;
Set Nodes = objXML.SelectNodes("//basla[@kayit_id='15']")
For i = 0 To Nodes.length - 1
	Response.Write "kayıt id : " & Nodes(i).getAttribute("kayit_id")& "<br>"
	Response.Write "kayıt adı : " & Nodes(i).childNodes(0).text & "<br>"
	Response.Write "not : " & Nodes(i).childNodes(1).text & "<br><br>"
Next

Response.Write "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~<br><br>"

' kayit_id'si 15 olan basla node'larının ilkini seçmek için;
Set Node = objXML.SelectSingleNode("//basla[@kayit_id='15']")
Response.Write "att'nin değeri  : " & Node.getAttribute("att")& "<br>"
Response.Write "kayıt id : " & Node.getAttribute("kayit_id")& "<br>"
Response.Write "kayıt adı : " & Node.childNodes(0).text & "<br>"
Response.Write "not : " & Node.childNodes(1).text & "<br><br>"
%>

[CreaNext]

@absconder her seferinde yardımcı oluyorsun. Çok teşekkür ederim.

[absconder]

biraz yardimci oluyorsam, ne mutlu bana

[karabela24]

absconder vermiş olduğun örnekten yola çıkarak XML de veri güncellemeye çalıştım.yalnız veri güncelle dediğimde XML içerisindeki tüm yazıları siliyor.Nasıl veri güncelleme yapabilirim acaba?

XML YAPISI
<content>
<urun id="1"></urun>
<urun id="2"></urun>
</content>

ASP KODU
set objXML = server.CreateObject("Microsoft.XMLDOM")
success = objXML.load("deneme/dene.XML")

If CBool(success) then
objXML.DocumentElement.childNodes(0).getAttribute( "id") ="deneme"
end if

objXML.save(server.MapPath("deneme/dene.XML"))

[absconder]

objXML.DocumentElement.childNodes(0).setAttribute( "id", "deneme")

olması lazım

[karabela24]

Sub yordamı kullanılırken ayraçlar kullanılamaz hatası alıyorum

[abdagli]

karabela24 tarafından gönderilen mesaj:

Sub yordamı kullanılırken ayraçlar kullanılamaz hatası alıyorum

Call ile bir sub çağrılırken parantezleri kullanmamalısın. Call(...) yerine Call ... şeklinde kullanmalısın.

[karabela24]

abdagli objXML.DocumentElement.childNodes(0).setAttribute( "src","devranreis") bu satırda hata veriyor.Burayı ne şekilde düzenlemeliyim?

[abdagli]

karabela24 tarafından gönderilen mesaj:

abdagli objXML.DocumentElement.childNodes(0).setAttribute( "src","devranreis") bu satırda hata veriyor.Burayı ne şekilde düzenlemeliyim?

Bir de şu şekilde dene:
objXML.DocumentElement.childNodes(0).setAttribute "src","devranreis"