[soncizgi]

Merhaba arakdaşlar. Ekrandaki bir movie clip'i zamana bağlı olarak nasıl hareket ettirebilirim. Mesela kup_mc diye bir movie clip var, diyelim yukarıdan aşağıya 50 birim kaydıracam. _y=50 iken _y=100 'e getircem. tabi _y'sini 1'er birim artırarak. Fakat aşağıya inerken bekleme süresine göre hareket etmesini istiyorum. Yani 5 saniyede bir yada 10 saniyede bir aşağı kaymasını istiyorum. _y=100 oluncada durmasını istiyorum. Umarım anlatabilmişimdir. Yardımlarınız için şimdiden teşekkürler.

[komplike]

MovieClip'e şu AS kodlarını yazarsan işini görür.

 onClipEvent (load) {
	var flag:Number = getTimer();
	var sure:Number = 5;	// Kaç saniyede bir hareket edecek
	var bitis:Number = 100;	// Nerede duracak
	var artis:Number = 1;	// Kaç piksel hareket edecek
}

onClipEvent (enterFrame) {
	if (((getTimer()-flag) >= (sure*1000)) && this._y != bitis) {
		this._y += artis;
	}
}

veya

 onClipEvent (load) {
	var sure:Number = 5;	// Kaç saniyede bir hareket edecek

	function kaydir(obj:Object,d:Number,l:Number):Void {

		/*
			obj : Hareket ettireceğin nesne
			d   : Kaç piksel hareket edecek
			l   : Nerede duracak

		*/

		if (obj._y != l) {
			obj._y += d;
		}
	}

	setInterval(kaydir,(sure*1000),this,1,100);
}

Kodları denemedim ama yüksek ihtimalle çalışmaları lazım.

[soncizgi]

Arkadaşım çok sağol. 1. kod verilen süreden sonra harekete geçiyor ve kayarken artık süreyi göz ardı ediyor. Ama 2.si tam istediğim gibi. Ellerine sağlık, teşekkürler.

[komplike]

Rica ederim

Bu arada ilk kodu düzeltiyorum, bir şeyi atlamışım.

onClipEvent (load) {
	var sure:Number = 5;	// Kaç saniyede bir hareket edecek
	var bitis:Number = 100;	// Nerede duracak
	var artis:Number = 1;	// Kaç piksel hareket edecek
	var flag:Number = getTimer()-(sure*1000);
}

onClipEvent (enterFrame) {
	if (((getTimer()-flag) >= (sure*1000)) && this._y != bitis) {
		this._y += artis;
		flag = getTimer();
	}
}

Şimdi; hem hemen başlayacak hem de olması gerektiği gibi 5 saniyede bir hareket ettirecek.

Fakat ilk mesajımdaki 2. kod işine yaradıysa da olur. Hatta o kod bundan daha "güzel" bana kalırsa, setInterval'ı boşuna koymadı adamlar çünkü