[ugursamsa]

flash programını kullanarak kare karalamaca oyununu yapmak istiyorum.

Kare karalamacayı bilemeyenler için anlatayım. Mesela elinizde 20x20 kare bir alan var. Bunlarda kare kare ayrılmış. Bu karelerden bazılarının boş kalması bazılarınınsa karalı olması gerekiyor.

Şimdi ben tüm karelerin tek tek değil de mouse'a basılı tutulduğu sürece hangi karenin üzerine gelirse o zaman siyaha boyanmasını istiyorum. Böyle bir şey mümkün müdür?

[Gazing]

Evet mümkündür Şu anda evde değilim.Eve gelince ufak bir örnek hazırlarım.Yalnız kodlama AS3 mü AS2 mi olacak?

[ugursamsa]

Gazing ilgine teşekkürler. flash 8 kullanarak hazırlamayı düşünüyorum. AS2 ya da AS3'ün ikisi de geçerli ise flash 8 için benim açımdan problem yok. Aslına bakarsan arasındaki farkı çok bilmiyorum

[Gazing]

Bu kodu aynen AS2 kod penceresine yapıştır ve test et:

PHP Code:

var matris:Array = new Array();
var mSatir:Number = 10;
var mSutun:Number = 10;
var matrisScale:Number = 50;
var id:Number = 0;
//
var holder_mc:MovieClip = _root
//
function kareOlustur(holder_mc:MovieClip) {
    for (b=0; b<mSatir; b++) {
        for (i=0; i<mSutun; i++) {
            var kare_mc:MovieClip = holder_mc.createEmptyMovieClip("kare_mc"+id, holder_mc.getNextHighestDepth());
            //
            kare_mc.x = i*matrisScale;
            kare_mc.y = b*matrisScale;
            //
            kare_mc.filled = false;
            kare_mc.refresh = false;
            //
            kareCiz(kare_mc);
            //
            matris.push(kare_mc);
            id++;
        }
    }
}
function kareCiz(kare_mc:MovieClip) {
    kare_mc.clear();
    kare_mc.lineStyle(1,0x000000);
    kare_mc.moveTo(0,0);
    kare_mc.lineTo(matrisScale,0);
    kare_mc.lineTo(matrisScale,matrisScale);
    kare_mc.lineTo(0,matrisScale);
    kare_mc.endFill();
    //
    kare_mc._x = kare_mc.x;
    kare_mc._y = kare_mc.y;
}
function kareBoya(kare_mc:MovieClip) {
    kare_mc.clear();
    kare_mc.beginFill(0x000000);
    kare_mc.moveTo(0,0);
    kare_mc.lineTo(matrisScale,0);
    kare_mc.lineTo(matrisScale,matrisScale);
    kare_mc.lineTo(0,matrisScale);
    kare_mc.endFill();
    //
    kare_mc._x = kare_mc.x;
    kare_mc._y = kare_mc.y;
}
function renderStart() {
    onEnterFrame = function () {
        for (b=0; b<matris.length; b++) {
            if (matris[b].hitTest(holder_mc._xmouse, holder_mc._ymouse)) {
                if(matris[b].refresh==false) {
                    matris[b].filled==false?kareBoya(matris[b]):kareCiz(matris[b]);
                    matris[b].filled==false?matris[b].filled=true:matris[b].filled=false;
                    matris[b].refresh=true;
                }
            }
        }
    };
}
function renderStop() {
    delete onEnterFrame;
    refreshAll()
}
function refreshAll() {
    for (b=0; b<matris.length; b++) {
        matris[b].refresh=false;
    }
}
onMouseDown = function () {
    renderStart();
};
onMouseUp = function () {
    renderStop();
};
kareOlustur(this); 


[ugursamsa]

Çok güzel. Ellerine sağlık.

Bu uygulamaya sağ tıklama ile başka renk ya da karenin ortasına nokta koyacak kodları eklediğimde tam olarak istediğime ulaşmış olacağım. Proje bittiğinde buradan yazarım. Çok teşekkürler yardımın için.