ASP Fonksiyon Kütüphanesi

soul · 07.08.2003

Kişisel ASP library' imden sık kullandığım fonksyonlar,
Sanırım ki işinize yarayacaktır. Bazılarını yazalı 2 sene oldu, haal aktif şekilde kullanmaktayım;

Tüm fonksiyonları da yavaş yavaş eklemeye çalışacağım;

File Exist v1.2
Serverda bir dosyanın bulunup bulunmadığını kontrol eder ve True / False olarak sonucu döndürür.
FSO gereklidir

Kod:

'***P13 ? File Exist v1.2 by Ferruh Mavituna
'//NFO//
'	Check server for a file
'//ARGUMENTS//
'	filename(string)
'//RETURN//
' True / False
'//SAMPLE// 
'	If P13_FileExist("imgs/xx.jpg") Then Response.write "<img src=""imgs/xx.jpg"">"
Function P13_FileExist(byval filename)
	If filename <> "" Then
		Dim p13fso
		Set p13fso = server.CreateObject("Scripting.FileSystemObject")
		If p13fso.FileExists(server.Mappath(filename)) Then p13_FileExist = True Else P13_FileExist = False
	Else
		P13_FileExist = False
	End If
End Function

Random Text v1.2
Rasgele metin oluşturucu, Özellikle şifre oluştururken çok faydalı.

Kod:

'***P13 Random Text v1.2 by Ferruh Mavituna
'//NFO//
'	Generate random texts by select lenght and pattern
'//ARGUMENTS//
'	lenght : Lenght of string will be generate
'	rp_chars : Adds Special pattern for generate
'	lcases : Include Lowercase Characters (1=active/0=deactive)
'	ucases : Include Uppercase Characters (1=active/0=deactive)
'	exchars : Include Extra Characters (1=active/0=deactive)
'	numbers : Include Numbers(1=active/0=deactive)
'//SAMPLES// 
'	Response.Write P13_RandomPass(7,"p13studio",0,0,0,0)
'		This will generate some random texts just from p,1,3,s,t,d,i,o and this texts lenght is 7
'	Response.Write P13_RandomPass(10,"*+-",1,1,0,0)
'		This will generate some random texts just from lowercases, uppercases, and *,+,-  also this texts lenght is 10

Function P13_RandomPass(lenght,rp_chars,lcases,ucases,exchars,numbers)
Dim rp_lchars, rp_uchars, rp_,rp_ranval, rp_RndInt, rp_exchars, rp_numbers
If lenght = 0 Then lenght = 7

	rp_lchars = "abcdefghijklmnopqrstuvwxyz"
	rp_uchars = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
	rp_exchars = "`~!@#$%^&*()-_=+[{]}\\|;:"""'\,<.>/? "
	rp_numbers = "0123456789"

	If lcases = 1 Then rp_chars = rp_chars & rp_lchars
	If ucases = 1 Then rp_chars = rp_chars & rp_uchars
	If exchars = 1 Then rp_chars = rp_chars & rp_exchars
	If numbers = 1 Then rp_chars = rp_chars & rp_numbers
	
	If rp_chars = "" Then rp_chars = "p13studio"

	For i = 1 to lenght
		Randomize Timer
		rp_RndInt = Int(Rnd*Len(rp_chars)+1)
		rp_ranval = rp_ranval & Mid(rp_chars,rp_RndInt,1)
	Next

	P13_RandomPass = rp_ranval
End Function

Special Variable Writer
Bunu çoklu dil desteği olan projelerde kullanıyorum, translate olayı için kullanışlı.

Kod:

'***P13 Special Variable Writer by Ferruh Mavituna
'//NFO//
'	Replace a special $author with an ASP Variable
'//ARGUMENTS//
'	valx = All text
'	variablex = ASP Variable (For two or more variables split them by (-) negotation sign)
'	repvariable = $Variable (For two or more $variables split them by (-) negotation sign)
'//PLEASE NOTE//
'	If you use multiple variable change use variables same order
'	DO		:	val1-val2,$val1-$val2
'	DON'T	:	val1-val2,$val2-$val1
'//SAMPLES//
'	P13_Variable(l.Fields.Item("ranktitle").Value,deger,"$rank")'
'	P13_Variable(l.Fields.Item("ranktitle").Value,deger-deger2,"$rank-$rank2")'

Function P13_Variable(valx,variablex, repvariable)
Dim vararr, repvararr, vari
	If valx <> "" Then 
		P13_Variable = valx
		vararr = Split(variablex,"-",-1,1)
		repvararr = Split(repvariable,"-",-1,1)
		For vari = 0 to Ubound(vararr)
			P13_Variable = Replace(P13_Variable,Trim(repvararr(vari)),Trim(vararr(vari)),1,-1,1)
		Next
	End If
End Function

Lettergraph v1.1
Metni otomatik ayırıp harfleri resim olarak çağırıyor.
Mesela "GO" kelimesi, "<img src="g.gif"><img src="o.gif">" gibi bir hale geliyor.

Kod:

'***Lettergraph  v1.1 by Ferruh Mavituna
'//NFO//
'	Write Letters as images
'//ARGUMENTS//
'	valx : Text  (alphanumeric)
'//SAMPLE// 
'	Response.Write  P13_Lettergraph("soul")
' >>> Need alphabet folder <<<
'******************************
'Function P13_Lettergraph(valx,folder)
'	If folder = "" Then folder ="alphabet"
'******************************
Function P13_Lettergraph(valx)
	Dim ix, ix2, valxarr, curletter, lmod
	If valx <> "" Then
		valxarr = Split(Trim(valx)," ")
		For ix2 = 0 to Ubound(valxarr)
			For ix = 1 to Len(valxarr(ix2))
				
				curletter = Left(valxarr(ix2),1)
					'// Turkish Character Map
						If Ucase(curletter) = "Ş" Then curletter = "s2"
						If Ucase(curletter) = "Ğ" Then curletter = "g2"
						If Ucase(curletter) = "i" Then curletter = "i2"
						If Ucase(curletter) = "Ü" Then curletter = "u2"
						If Ucase(curletter) = "Ö" Then curletter = "o2"

				If ix2 mod 2 Then lmod = "2" Else lmod = ""

				P13_Lettergraph = P13_Lettergraph & "<img src=""13mg/lt" & lmod &"/" & curletter &".gif"" alt=""" & curletter & """ />"
				valxarr(ix2) = Right(valxarr(ix2),Len(valxarr(ix2))-1)
			Next
			
			If ix2 < Ubound(valxarr) Then P13_Lettergraph = P13_Lettergraph & "<img src=""13mg/lt/dot.gif"" alt=""dot"" />"

		Next
	End If
End Function

Timer
Bu en sevdiklerimden biri.

Sayfanızın üzerine bir timer koyun;

Kod:

Dim Xtimer
Xtimer = Timer

Sayfanın sonunda da bu fonksiyonu çağırın;

Kod:

Response.Write P13_Timer(timer-timex)

Sayfanın işlem süresi "00:02" gibi şekilde gösterilecek.

Fonksiyon;

Kod:

'***P13 Timer v1.3 by Ferruh Mavituna
'//NFO//
'	Make clock tiemr format
'//ARGUMENTS//
'	timex : Time as Second
'//RETURN// 
'Some String Like 00:15
'//SAMPLE// 
'	Response.Write P13_Timer(timer)
Function P13_Timer(timex)
Dim mn, sc, mntxt, sctxt
	If isnumeric(timex) Then
		'// Format Minute
		mn = Round(timex/60,0)
		if mn < 0 Then mn = 0
		if mn < 10 Then mntxt = "0"
		mntxt = mntxt & mn

		'// Format Second
		sc = Round(timex Mod 60,0)
		if sc < 0 Then sc = 0
		if sc < 10 Then sctxt = "0"
		sctxt = sctxt & sc
		
		'// Final
		P13_Timer = mntxt & ":" & sctxt
	Else
		P13_Timer = "Error value is not numeric !"
	End If
End function

Devamı gelecek... Bunlarda da aslında çok geliştirmeler oldu, onları da düzenleyip generic bir hale sokarak yayınlamaya çalışacağım.

soul · 25.09.2003

Simple site Map Maker, Recursive
Basit şekilde site haritası oluşturan bir fonksiyorn, aynı zamanda genelde yeni başlayanları zorluk çektiği recursive (yineleyen) fonksiyonlara da bir başlangıç taşıyabilir.

Sitepath adresi verirken dikkatli olun eğer 20-30 adet alt klasörü varsa sayfanın işlemesi uzayabilir.

Kod:

'//***************************************************/
'// Ferruh Mavituna | freelance Designer & Developer
'// ferruh@mavituna.com | http://ferruh.mavituna.com
'// Simple site Map Maker func !
'//***************************************************/
Dim SitePath
'SitePath = server.Mappath("../../") 
SitePath = server.Mappath("/")

Response.Write "<h1>&quot;" & SitePath & "&quot; Folders</h1>"

'// Call Tree
	TreeList SitePath,SitePath,0



'//***************************************************/
'// Main Func. !
'//***************************************************/
Function TreeList(byval SitePath,byval Folders,byval sublevel)
	Dim FSO, FolderName, tmpstr, i, Subcount, tmpName
	Set FSO = CreateObject("Scripting.FileSystemObject")
	Set Folders=FSO.GetFolder(Folders)

		'// Loop Folders
		For Each FolderName In Folders.subfolders		
			tmpName = Right(FolderName,Len(FolderName)-Len(SitePath)-1)
			Subcount = FolderName.subfolders.count
			'// Levels
			tmpstr=""
			For i=1 To sublevel
				tmpstr = tmpstr & "&nbsp;. "
			Next
			
			'// Print
			Response.Write tmpstr &  tmpName & "<br />" & vbNewline

			'// Call this func.  
			If Subcount>0 Then TreeList SitePath, FolderName, sublevel+1
			
			'// Flush !
			'Response.Flush
		Next
	
	'// Kill
	Set FSO=Nothing
	Set Folders=Nothing
End Function

soul · 25.09.2003

İlk Harfleri Büyüt
Çok eskiden yazdığım kelimelerin ilk harflerini büyütüp gerisini küçülten bir fonksyion; otomatik gelişen sitelerde "web SiTem" gibi başlıklara atanlara karşı faydalı.

Kod:

<%
Function complex(metin)
splitter = " "
If metin <> "" Then
	xarr = Split(metin, splitter)
	For i = 0 to Ubound(xarr)
		xmetin = Trim(xarr(i))
		If xmetin <> "" Then
		xmetin = Lcase(xmetin)
		xstletter = Ucase(Left(xmetin,1))
			'// You can add here your language characters
			xstletter = Replace(xstletter,"i","İ", 1, -1) 'Ý
		xmetin = Right(xmetin, Len(xarr(i)) - 1)
			'// You can add here your language characters
			xmetin = Replace(xmetin,"İ","i", 1, -1) 'Ý
		xmetin = xstletter & xmetin
	End if
		zmetin = zmetin & " " & xmetin
	Next
End if
complex = zmetin
End Function
%>
<%=complex("heLLo")%>

soul · 25.09.2003

Stringten Array'e
Verdiğini stringin karakterlerinden bir Array Dizisi döndürür;

Kod:

'******************************************************************
'// Convert a String to Array by Ferruh Mavituna
'******************************************************************
Function fm_str2Arr(byVal Str, byRef Arr)
	Dim i, StrLen
	StrLen = Len(Str)-1
	
	Redim Arr(StrLen)

	For i = 0 to StrLen
		Arr(i)=Left(Str,1)
		If Len(Str)>0 Then Str=Right(Str,Len(Str)-1)
	Next
End Function

soul · 25.09.2003

E-mail Kontrol
Verilen e-mail adresinin geçerli olup olmadığını (stringe bakarak) belirler ve True/False Boolean döndürür.

not : Regular Expression benim tarafımdan yazılmadı. Sahibini de hatırlamıyorum maalesef.

Kod:

Function P13_EmailChecker(email)
	Dim regEx, Match, Matches
	If email <> "" Then
		Set regEx = New RegExp
		regEx.Pattern = "^([a-zA-Z0-9_\-\.]+)@((\[[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3}\.)|(([a-zA-Z0-9\-]+\.)+))([a-zA-Z]{2,4}|[0-9]{1,3})(\]?)$"
		regEx.IgnoreCase = True
		If regEx.Test(email) Then P13_EmailChecker = True Else P13_EmailChecker = False
	End If
End Function

soul · 25.09.2003

Dosya Adını Değiştirme

Kod:

'//Arguments : dosyanın eski adı adı, yeni adı

Function P13_Renamer (filename, renamename)
	Dim FSORename
	Set FSORename = CreateObject("Scripting.FileSystemObject")
	FSORename.MoveFile filename, renamename
	
	Set FSORename = Nothing
End Function

Querystringi al - Numerik Olarak Getir
Eğer quesryrtign boş veya numerik değilse 0 a eşit olur.

Kod:

'******************************************************************
'fm_QNStr() v1.1 by Ferruh Mavituna
'******************************************************************
'//NFO//
'	Get Querystring get it as a numeric value, If it's not numeric it return 0
'//ARGUMENTS//
'	Qstring = Querystring Name
'//RETURN//
'	Numeric value from Querystring
'//SAMPLES//
'	QueryId = fm_QNStr("id")
Function fm_QNStr(byVal Qstring)
	Qstring= Trim(Request.Querystring(Qstring))
	If NOT IsNumeric(Qstring) Then fm_QNStr = 0 Else fm_QNStr = Qstring
End Function

05.10.2003

merhaba ben bu kodları denedim ama yapamadım bunları nasıl kullanıcam belli taglerin arasınamı koyucaz yoksa... ben heryere koydum denedim yapamadım

soul · 05.10.2003

Bunların hepsi fonksyion, mesela;

E-mail Kontrol (Function P13_EmailChecker(email))

fonksiyonunu tüm kodlarını yukarıdaki mesajdan al ve sayfana kopyala.
Ondan sonra da sayfana

Kod:

Response.Write P13_EmailChecker(test@test)

yaz. Çalıştır

Sayfaya True yazdıysa e-mail geçerli False yazdıysa e-mail geçersizdir.

Bu ve bunun gibi sana vakit kazandıracak fonksiyonlar var burada. Tabii ki kullanabilmek için temel ASP bilgisi ve Foksiyon kullanımı bilgisine sahip olman gerekli.

05.10.2003

anladımda ben sadece e-mail kontrolu için sormadım. ben bu kodları aldım DW de boşbi sayfaya yapıştırıdm fakat olmadı

mesela bunu nasıl kullanırım

Lettergraph v1.1
Metni otomatik ayırıp harfleri resim olarak çağırıyor.
Mesela "GO" kelimesi, "<img src="g.gif"><img src="o.gif">" gibi bir hale geliyor.

soul · 07.10.2003

Yapman gereken tek şey aşağıdakini sayfaya koymak;

<%Response.Write P13_Lettergraph("soul")%>

Bir de tabii ki "13mg/lt" isimli bir klasörde a.gif, b.gif vs. gibi tüm karakterlerin olması gerekiyor.

25.09.2003	#5 (permalink)
soul Üyelik Tarihi: 13.07.2000 Yer: LND Mesaj: 4,275	E-mail Kontrol Verilen e-mail adresinin geçerli olup olmadığını (stringe bakarak) belirler ve True/False Boolean döndürür. not : Regular Expression benim tarafımdan yazılmadı. Sahibini de hatırlamıyorum maalesef. Kod: Function P13_EmailChecker(email) Dim regEx, Match, Matches If email <> "" Then Set regEx = New RegExp regEx.Pattern = "^([a-zA-Z0-9_\-\.]+)@((\[[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3}\.)\|(([a-zA-Z0-9\-]+\.)+))([a-zA-Z]{2,4}\|[0-9]{1,3})(\]?)$" regEx.IgnoreCase = True If regEx.Test(email) Then P13_EmailChecker = True Else P13_EmailChecker = False End If End Function __________________ FERRUH.MAVİTUNA - İnanmıyorum, yeni site!

05.10.2003	#8 (permalink)
soul Üyelik Tarihi: 13.07.2000 Yer: LND Mesaj: 4,275	Bunların hepsi fonksyion, mesela; E-mail Kontrol (Function P13_EmailChecker(email)) fonksiyonunu tüm kodlarını yukarıdaki mesajdan al ve sayfana kopyala. Ondan sonra da sayfana Kod: Response.Write P13_EmailChecker(test@test) yaz. Çalıştır Sayfaya True yazdıysa e-mail geçerli False yazdıysa e-mail geçersizdir. Bu ve bunun gibi sana vakit kazandıracak fonksiyonlar var burada. Tabii ki kullanabilmek için temel ASP bilgisi ve Foksiyon kullanımı bilgisine sahip olman gerekli. __________________ FERRUH.MAVİTUNA - İnanmıyorum, yeni site!

07.10.2003	#10 (permalink)
soul Üyelik Tarihi: 13.07.2000 Yer: LND Mesaj: 4,275	Yapman gereken tek şey aşağıdakini sayfaya koymak; <%Response.Write P13_Lettergraph("soul")%> Bir de tabii ki "13mg/lt" isimli bir klasörde a.gif, b.gif vs. gibi tüm karakterlerin olması gerekiyor. __________________ FERRUH.MAVİTUNA - İnanmıyorum, yeni site!

05.10.2003	#7 (permalink)
ReiS Mesaj: n/a	merhaba ben bu kodları denedim ama yapamadım bunları nasıl kullanıcam belli taglerin arasınamı koyucaz yoksa... ben heryere koydum denedim yapamadım

05.10.2003	#9 (permalink)
ReiS Mesaj: n/a	anladımda ben sadece e-mail kontrolu için sormadım. ben bu kodları aldım DW de boşbi sayfaya yapıştırıdm fakat olmadı mesela bunu nasıl kullanırım Lettergraph v1.1 Metni otomatik ayırıp harfleri resim olarak çağırıyor. Mesela "GO" kelimesi, "<img src="g.gif"><img src="o.gif">" gibi bir hale geliyor.